MODULE gfx;

(* The tv toolkit running on the tigr graphics backend instead of a terminal.

   Build (from tvision-m2/examples):
       make gfx
   Needs tigr.o and helper.o built in ../modula2 (gcc -c ...). *)

FROM InOut IMPORT WriteString, WriteLn;
FROM SYSTEM IMPORT ADR, CAST;
IMPORT tv, tvg;

CONST
    mNew   = 100;
    mQuit  = 101;
    mAbout = 102;
    mCut   = 103;
    mCopy  = 104;

VAR
    w1, w2, status : tv.ViewPtr;
    input, check, r1, r2, listv : tv.ViewPtr;
    t : tv.ViewPtr;
    listData : tv.ListData;
    e : tv.Event;
    quit : BOOLEAN;
    cmd : INTEGER;
    sender : tv.ViewPtr;
    discard : INTEGER;
    tmp, msgbuf : ARRAY [0..63] OF CHAR;

PROCEDURE SetStatus(s : ARRAY OF CHAR);
BEGIN tv.SetText(status, s); tvg.Finish END SetStatus;

BEGIN
    IF NOT tvg.InitGfx("tvision-m2 - tigr backend", 90, 30) THEN
        WriteString("cannot open the graphics window"); WriteLn; HALT
    END;

    (* menu bar *)
    tv.MenuBarInit;
    tv.MenuAdd("File");
    tv.MenuItemAdd("New", mNew);
    tv.MenuSep;
    tv.MenuItemAdd("Quit", mQuit);
    tv.MenuAdd("Edit");
    tv.MenuItemAdd("Cut", mCut);
    tv.MenuItemAdd("Copy", mCopy);
    tv.MenuAdd("Help");
    tv.MenuItemAdd("About", mAbout);

    status := tv.NewView(tv.VText, 0, tv.Rows() - 1, tv.Cols(), 1);
    tv.SetText(status, " F10/click: menu   Tab: next   mouse: drag/click   Esc: quit");
    tv.AddView(tv.Desk(), status);

    w1 := tv.NewView(tv.VWindow, 3, 2, 56, 16);
    tv.SetText(w1, "Editor");
    t := tv.NewView(tv.VText, 5, 4, 24, 1);
    tv.SetText(t, "Name:"); tv.AddView(w1, t);
    input := tv.NewView(tv.VInput, 12, 4, 32, 1);
    tv.SetText(input, "Modula-2"); tv.AddView(w1, input);
    check := tv.NewView(tv.VCheck, 12, 6, 24, 1);
    tv.SetText(check, "Enabled"); check^.flags := tv.vfSelected; tv.AddView(w1, check);
    t := tv.NewView(tv.VText, 5, 8, 6, 1);
    tv.SetText(t, "Mode:"); tv.AddView(w1, t);
    r1 := tv.NewView(tv.VRadio, 12, 8, 12, 1);
    tv.SetText(r1, "Fast"); r1^.flags := tv.vfSelected; tv.AddView(w1, r1);
    r2 := tv.NewView(tv.VRadio, 26, 8, 12, 1);
    tv.SetText(r2, "Safe"); tv.AddView(w1, r2);

    listData.items[0] := "Alpha";   listData.items[1] := "Bravo";
    listData.items[2] := "Charlie"; listData.items[3] := "Delta";
    listData.items[4] := "Echo";    listData.items[5] := "Foxtrot";
    listData.count := 6;
    listv := tv.NewView(tv.VList, 5, 10, 22, 5);
    listv^.list := CAST(tv.ListDataPtr, ADR(listData));
    tv.AddView(w1, listv);

    t := tv.NewView(tv.VButton, 30, 15, 8, 1);
    tv.SetText(t, "OK"); tv.SetTag(t, tv.cmOK); tv.AddView(w1, t);
    t := tv.NewView(tv.VButton, 41, 15, 10, 1);
    tv.SetText(t, "Close"); tv.SetTag(t, tv.cmCancel); tv.AddView(w1, t);
    tv.AddView(tv.Desk(), w1);

    w2 := tv.NewView(tv.VWindow, 42, 8, 34, 7);
    tv.SetText(w2, "About");
    t := tv.NewView(tv.VText, 44, 10, 30, 1);
    tv.SetText(t, "tvision-m2 on tigr"); tv.AddView(w2, t);
    t := tv.NewView(tv.VText, 44, 11, 30, 1);
    tv.SetText(t, "Same view tree, windowed output."); tv.AddView(w2, t);
    tv.AddView(tv.Desk(), w2);

    tv.BringToFront(w1);
    tv.FocusView(input);
    tvg.Finish;

    quit := FALSE;
    WHILE NOT quit DO
        IF tvg.ReadEvent(e) THEN
            IF (e.kind = tv.evKey) AND (e.key = tv.kEsc) THEN
                quit := TRUE
            ELSE
                cmd := tv.HandleEvent(e);
                sender := tv.Sender();
                IF cmd = mQuit THEN
                    quit := TRUE
                ELSIF cmd = mAbout THEN
                    discard := tv.MessageBox("About", "tvision-m2 - tigr backend", tv.mbOK);
                    SetStatus(" About closed")
                ELSIF cmd = tv.cmOK THEN
                    discard := tv.MessageBox("Info", "You pressed OK.", tv.mbOK)
                ELSIF cmd = tv.cmCancel THEN
                    tv.DelView(w1)
                ELSIF cmd >= 100 THEN
                    tv.CopyText(msgbuf, "Command #");
                    tv.IntToText(tmp, cmd, 0);
                    tv.AppendText(msgbuf, tmp);
                    SetStatus(msgbuf)
                END
            END;
            IF NOT quit THEN tvg.Finish END
        END;
        IF tvg.Closed() THEN quit := TRUE END
    END;

    tvg.Done
END gfx.